(SKU:RB-02S020)DS18B20數(shù)字溫度傳感器

產(chǎn)品概述

2014年最新推出的DS18B20數(shù)字溫度傳感器采用美國(guó)DALLAS公司生產(chǎn)的DS18B20一總線數(shù)字溫度感測(cè)元件其測(cè)溫范圍 －55℃～＋125℃，固有測(cè)溫分辨率0.5℃，支持多點(diǎn)組網(wǎng)功能，多個(gè)DS18B20可以并聯(lián)在唯一的三線上，實(shí)現(xiàn)多點(diǎn)測(cè)溫，測(cè)量結(jié)果以9~12位數(shù)字量方式串行傳送。 DS18B20數(shù)字溫度傳感器可在各種單片機(jī)控制器上應(yīng)用，尤其在Arduino控制器上更為簡(jiǎn)單，現(xiàn)成庫(kù)函數(shù)調(diào)用，即可完成溫度測(cè)量，通過(guò)3P傳感器連接線插接到Arduino專用傳感器擴(kuò)展板上，可以非常容易地實(shí)現(xiàn)與環(huán)境溫度感知相關(guān)的互動(dòng)作品。

規(guī)格參數(shù)

1. 類型：數(shù)字模塊（一總線接口）
2. 可用于檢測(cè)周圍空氣溫度
3. 溫度測(cè)量范圍：－55℃～＋125℃
4. 測(cè)量精度：±0.5 °C（-10 °C至+85 °C范圍內(nèi)）
5. 9位～12位A/D轉(zhuǎn)換精度
6. 分辨率：0.5℃
7. 供電電壓：3.3V或5V

接口定義

• S：輸出信號(hào)
• +：電源(VCC)
• -：地(GND)

使用方法

硬件設(shè)備

我們使用Arduino控制器來(lái)做個(gè)測(cè)試，要用到硬件設(shè)備如下：

1. Arduino控制器×1
2. Arduino 傳感器擴(kuò)展板×1
3. DS18B20 溫度傳感器模塊×1
4. 通用3P傳感器連接線×1
5. USB 數(shù)據(jù)通信線×1

接線方法

程序1接線圖

程序2接線圖

例子程序1

DS18B20溫度傳感器庫(kù)文件下載

如程序1接線圖所示，使用傳感器連接線將DS18B20 溫度傳感器連接到Arduino傳感器擴(kuò)展板的數(shù)字接口。先把下載的庫(kù)文件解壓縮到你的Arduino安裝目錄下的hardware\libraries 里面。然后將代碼編譯后下載到Arduino里，就可以在串口助手窗口上顯示測(cè)得的當(dāng)前值。

#include <OneWire.h>
#include <DallasTemperature.h>
 
// 定義DS18B20數(shù)據(jù)口連接arduino的2號(hào)IO上
#define ONE_WIRE_BUS 2
 
// 初始連接在單總線上的單總線設(shè)備
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
 
void setup(void)
{
  // 設(shè)置串口通信波特率
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");
 
  // 初始庫(kù)
  sensors.begin();
}
 
void loop(void)
{ 
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // 發(fā)送命令獲取溫度
  Serial.println("DONE");
   
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}
 

例子程序2

DS18B20溫度傳感器庫(kù)文件下載

如程序2接線圖所示，使用傳感器連接線將DS18B20 溫度傳感器連接到Arduino傳感器擴(kuò)展板的數(shù)字接口。先把下載的庫(kù)文件解壓縮到你的Arduino安裝目錄下的hardware\libraries 里面。然后將代碼編譯后下載到Arduino里，就可以在串口助手窗口上顯示測(cè)得的當(dāng)前值。

#include <OneWire.h>
OneWire  ds(10);  // 連接arduino10引腳
 
void setup(void) {
  Serial.begin(9600);
}
 
void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
   
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
   
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }
 
  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
  
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 
 
  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end
   
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
   
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad
 
  Serial.print("  Data = ");
  Serial.print(present,HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();
 
  // convert the data to actual temperature
 
  unsigned int raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // count remain gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
    // default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");   
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}
 

程序效果

下載程序后可以通過(guò)Arduino軟件的串口查看DS18B20檢測(cè)的環(huán)境溫度。

應(yīng)用視頻

產(chǎn)品相關(guān)推薦

購(gòu)買地址

DS18B20 數(shù)字溫度傳感器

周邊產(chǎn)品推薦

Arduino DHT11 溫度傳感器
LM35線性溫度傳感器
土壤濕度傳感器

相關(guān)問(wèn)題解答

DS18B20 數(shù)字溫度傳感器數(shù)據(jù)波動(dòng)異常

相關(guān)學(xué)習(xí)資料

Adafruit的樹莓派教程 DS18B20溫度傳感器
奧松機(jī)器人技術(shù)論壇